標準ＴＴＬだけ（！）でCPUをつくろう！（組立てキットです！）
(ホントは７４ＨＣ、ＣＭＯＳなんだけど…）
［第６５３回］

●ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲ

前回は、ＧＥＴ　ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲを検出したところまで説明をいたしました。
ＰＩＣのプログラムは、それに応えて、ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲを送出する用意をします。
ＧＥＴ　ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲを検出したあとのプログラムは次のようになっていました。

;(1)"GET DESCRIPTOR('80'+'06')" received
	movf db3,w
	sublw 1; 1 or 2? 1:dev.descriptor 2:config descreptor
	bnz sendconf
;send DEVice DSCRPTR
	movlw 12
	cpfseq db6
	call resetADDR
	call setbd2
	call setbd0
	call setbd1	
	goto looptop

ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲを送出する準備をしているのはｓｅｔｂｄ２サブルーチンです。
下にｓｅｔｂｄ２サブルーチンを示します。

;ep0(IN) data set
setbd2
	call devdset1
	call setbd2odd
	movlw 1
	movwf bd2mk;=1
	return
;
setbd2odd
	lfsr 1,20b
	movlw 02;address high
	movwf POSTDEC1
	movlw 30;address low
	movwf POSTDEC1
	movlw 8;bytes
	movwf POSTDEC1	
	movlw 0c8
	movwf INDF1
	return

ｄｅｖｄｓｅｔ１サブルーチンがＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲをデータバッファにセットするサブルーチンです。このサブルーチンについてはあとで説明をします。
ｓｅｔｂｄ２ｏｄｄサブルーチンはｓｅｔｂｄ２サブルーチンの下にあります。
ＥＰ０（ＩＮ）のＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲに必要な値をセットします。
ＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲについては［第６３８回］、［第６３９回］で説明をしています。

ＥＰ０（ＩＮ）のＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲはアドレス２０８〜２０Ｂの４バイトです。
アドレス２０８はＢＵＦＦＥＲ　ＤＥＳＣＲＩＰＴＯＲの第１バイトＢＤ２ＳＴＡＴです。
そのビット７を１にすると、ＳＩＥに制御が移ってしまいます。
ですから、まずｄｅｖｄｓｅｔ１サブルーチンでＥＰ０（ＩＮ）バッファにデータをセットし、それからＢＵＦＦＥＲＥ　ＤＥＳＣＲＩＰＴＯＲの後ろのアドレスから値をセットしていって、最後にアドレス２０８のＢＤ２ＳＴＡＴをセットします。
ｓｅｔｂｄ２ｏｄｄサブルーチンがアドレス２０８からではなく、アドレス２０ｂから値をセットしているのはその理由からです。

アドレス２０ｂはデータバッファアドレスの上位バイト、２０ａは下位バイトを示す値をセットします。
ＥＰ０（ＩＮ）データバッファはアドレス２３０〜２３７の８バイトです。
アドレス２０９は送出するバイト数を示します。
ＵＳＢホストコントローラからのコマンドやそれに応えて送るデバイスディスクリプタなどのデータはＥＰ０を使ってコントロール転送モードで送信、受信します。
コントロール転送では１度に送信するバイト数は８バイトです。
８バイト以上あるデータは８バイトに区切って送ります。

ＥＰ０（ＩＮ）はＵＳＢホストコントローラにデータを送出するパイプです。
ＩＮ、ＯＵＴはホストコントローラから見た向きですから、ＰＩＣから見たときは入力、出力の動作はその名前の意味と逆になります。
ＥＰ０（ＯＵＴ）はＰｉｎｇ−Ｐｏｎｇ　Ｂｕｆｆｅｒの設定にしましたので、ＥＰ０（ＯＵＴ）のＤＡＴＡ０（ＥＶＥＮ）とＥＰ０（ＯＵＴ）のＤＡＴＡ１（ＯＤＤ）の２つのパイプを使います。
しかし、ＥＰ０（ＩＮ）はＰｉｎｇ−Ｐｏｎｇ　Ｂｕｆｆｅｒではありませんから、１つだけです。
でもデータを送信するときは、ＤＡＴＡ０とＤＡＴＡ１を交互に使い分けて送信しなければなりません。

ＵＳＢホストコントローラから送られてくるＧＥＴ　ＤＥＳＣＲＩＰＴＯＲなどのデータ送信要求コマンドはＤＡＴＡ０（ＥＶＥＮ）で送られてきます。
それに応えてＰＩＣが送信するＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲの最初の８バイトはＤＡＴＡ１（ＯＤＤ）になります。
アドレス２０８のＢＤ２ＳＴＡＴの値はＤＡＴＡ０とＤＡＴＡ１のときとでビットの一部が異なります。
ＢＤｎＳＴＡＴについては、［第６５１回］で説明をしました。
ＤＡＴＡ０（ＥＶＥＮ）のときは、ビット６＝０にします。
ＤＡＴＡ１（ＯＤＤ）のときはビット６＝１にします。
今回はＤＡＴＡ１を送りますから、アドレス２０８の値はＣ８（ビット６＝１）にします。

説明の順序が逆になってしまいましたが、下にＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲの最初の８バイトをデータバッファにセットするサブルーチン　ｄｅｖｄｓｅｔ１を示します。

;
;device descriptor data set
;
devdset1	
	lfsr 1,230
	movlw 12;size(bytes)
	movwf POSTINC1
	movlw 01;type(DEVUCE DESCRIPTOR)
	movwf POSTINC1
	movlw 00;USB version 02.00(Low)
	movwf POSTINC1
	movlw 02;(High)
	movwf POSTINC1
	movlw 00;HID class
	movwf POSTINC1
	movlw 00;SUB class
	movwf POSTINC1
	movlw 00;protocol code
	movwf POSTINC1
	movlw 08;max packet size of EP0
	movwf POSTINC1
	return

ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲの最初の８バイトの内容は、プログラムリストにコメントしている通りです。
第１バイトはＤＥＳＣＲＩＰＴＯＲのバイト数（１６進数）です。
ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲは１８バイトです。１６進数に直すと１２になります。
第２バイトはＤＥＳＣＲＩＰＴＯＲの種類を示します。
ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲは０１です。
第３、第４バイトはＵＳＢのバージョンを示します。
ＵＳＢのバージョンは２．０です。
第５バイトはｃｌａｓｓコードです。
ＨＩＤクラスは００にします。
第６、第７バイトも００にします。
第８バイトはＥＰ０の最大パケットサイズを示します。
８バイトです。

以上のプログラムを実行するとあとはＳＩＥ（ＰＩＣ内蔵のＵＳＢコントローラ）が、セットした値を決められたフォーマットでＵＳＢホストコントローラに向けて送出してくれます。

しかし。
待ってください。
ＤＥＶＩＣＥ　ＤＥＳＣＲＩＰＴＯＲは１８バイトあると書きました。
ここまでのところで、最初の８バイトはデータバッファにセットしましたから、それをＳＩＥが送出してくれるところまではわかりますが、残りの１０バイトはどうするのでしょう？

実はそのための仕掛けがさきほどお見せしたｓｅｔｂｄ２サブルーチンに仕込んであるのです。

	movlw 1
	movwf bd2mk;=1
	return

という部分です。
bd2mkはその仕掛けのためのワークレジスタです。
２０１０．１１．４ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る