２０１９．４．２８
前へ
次へ
ホームページトップへ戻る

［新連載］ＣＰＬＤ入門！
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
いつか使うことになるだろうと思ってはいたのですが。
何を今頃になって、というようなものですが。
ようやく本気で、ＣＰＬＤと四つに取り組みます。
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜



［第３９回］


●ＮＤ８０ＺＳＭのモニタプログラムリスト（一部）

今回の回路に対応して変更した部分のＮＤ８０ＺＳＭのモニタプログラムリストです。
ＮＤ８０ＺＳＭはＮＤ８０Ｚ３．５から７セグメントＬＥＤ回路、５Ｘ５キーボード回路、ＵＳＢインターフェース回路を外して、マイコン独立化セット、新マイコン独立化セットを接続して動作することに特化したボードでした。
しかしＮＤ８０ＺＳＭにできるだけローコストな７セグメントＬＥＤ回路と５Ｘ５キーボード回路を外付けできれば、ＮＤ８０Ｚ３．５のローコスト版にすることもできるのではないかと考えたことで、このところの作業となりました。
外付けする回路がＮＤ８０Ｚ３．５と同じ回路ならば、ＮＤ８０Ｚ３．５のモニタプログラムをそのまま使うことができます。
キーボード回路はＴＴＬロジック回路をそのままＥＰＭ７１２８ＳＬＣ８４に置き換えただけなので、ＮＤ８０Ｚ３．５のモニタプログラムをそのまま使えます。
しかし７セグメントＬＥＤ回路はＴＴＬ回路をＣＰＬＤに置き換えただけではなくて、ＤＭＡ回路だったところをＰＩＣ１６Ｆ５７に置き換えました。
もともとのＮＤ８０Ｚ３．５モニタプログラムでは７セグメントＬＥＤ表示はＤＭＡを利用しているために、ＲＡＭのセグメント表示用アドレスにセグメントデータを書き込むだけで済みました。
ＰＩＣ１６Ｆ５７を利用する今回の回路では、（ＤＭＡではないため）セグメントデータをただＲＡＭに書き込むだけでは表示されませんから、そこのところのプログラムをＰＩＣ１６Ｆ５７にセグメントデータを送るように書き換える必要があります。
下はその部分です。

07CF CDC005   LEDDP0:CALL SEGCG
07D2 E5       LEDDP:PUSH H
07D3 D5         PUSH D
07D4 C5         PUSH B
07D5 21F8FF     LXI H,DIG
07D8 0608       MVI B,08
07DA 0E88       MVI C,88
07DC CDE907   LEDDP2:CALL LEDDPS
07DF 23         INX H
07E0 0C         INR C
07E1 05         DCR B
07E2 C2DC07     JNZ LEDDP2
07E5 C1         POP B
07E6 D1         POP D
07E7 E1         POP H
07E8 C9         RET
              ;
              LEDDPS:;MOV A,C
                ;OUT 8E;adrs set
07E9 7E         MOV A,M
                ;OUT 8F
07EA ED         DB ED;OUT (C),A
07EB 79         DB 79;
07EC 1604       MVI D,04
07EE CDDF06     CALL D1_2;0.5msec wait
07F1 C9         RET
ＮＤ８０ＺモニタプログラムではＳＥＧＣＧ（１６進数データをセグメント表示用データに変換してＲＡＭの表示用アドレスに書き込むプログラム）をＣＡＬＬするだけで済んでいるところを、その後でＰＩＣ１６Ｆ５７にセグメントデータを送出するプログラムを追加しています。
実際にＰＩＣ１６Ｆ５７に送る部分はＬＥＤＤＰＳで行なっています。
この部分は試作の過程では当初は最初に表示アドレスを８ＥにＯＵＴし次に表示データを８ＦにＯＵＴし、それを８桁分繰り返すというプログラムでした。
これはＮＤ８０ＫＬ／８６ボードで行なっているやり方です。
その後にＺ８０の場合にはＯＵＴ　（Ｃ），ｒ命令を使えば回路もプログラムも簡単になることに気が付いたため、上記のプログラムになりました。
ＮＤ８０ＺモニタプログラムはＴＫ８０モニタプログラムとの対比から８０８０アセンブラを使って書いていますので、リストのように命令コードＥＤ７９を直接書いています。
ＯＵＴ　（Ｃ），Ａを実行すると、アドレスバスの下位８ビットに表示アドレスが出力され、データバスに表示データが出力されるので、それをＥＰＭ７１２８ＳＬＣ８４でラッチして、それをＰＩＣ１６Ｆ５７が読み込むという仕組みです。
０．５ｍｓはＰＩＣ１６Ｆ５７が７セグメント表示を行ないながら表示データを落とさないよう確実に読み取るためのウェイトです。
ＰＩＣ１６Ｆ５７は割込みが使えないのでウェイト時間は必要ですが、０．５ｍｓは十分な時間です。

●ＰＩＣ１６Ｆ５７のプログラムリスト（再掲）

ということで、次はＰＩＣ１６Ｆ５７のプログラムです。
ＰＩＣ１６Ｆ５７のプログラムリストは前回お見せしましたが、説明のため再掲します。

 
;;; 7seg LED disp for ND80ZUS/SM
;18/4/9 4/11 4/12 4/13
;from 7seg2j
;
; 16f57
; internal 12MHz
	#include <p16f5x.inc>
        __CONFIG _CP_OFF & _WDT_ON  & _HS_OSC
;
cf=0
zf=2
f=1
w=0
;
ledcntr equ 0a
tcn1 equ 0b
indata equ 0c
tcn0 equ 0d
;
;digit0 to digit7 are 10 to 17
;
     org 00
;
start
        movlw 0;a0-a3 out
        tris PORTA
        bsf PORTA,3
        movlw 1f;b7-b5 out b4-b0 in
        tris PORTB
        bsf PORTB,7;
        movlw 0
        tris PORTC;rc out
;
;start
        movlw 10
        movwf ledcntr
loop
        clrwdt
;leddisp        
        movf ledcntr,w
        movwf PORTA
        movwf FSR
        movf INDF,w
        movwf PORTC
        incf ledcntr,f
        btfss ledcntr,3
        goto t1ms
        movlw 10
        movwf ledcntr
;
        ;1ms wait
t1ms
        movlw 2
        movwf tcn0
t1ms1
        clrf tcn1
t1ms2
        clrwdt;1
        btfss PORTB,4;data ready? 2
        goto dataread;yes
t1ms3
        decfsz tcn1,f;1
        goto t1ms2;2---6/3*256=0.5ms
        decfsz tcn0,f
        goto t1ms1
        goto loop       
;datain
dataread
        bsf PORTB,5;bit4-7 read
        bcf PORTB,6
        bcf PORTB,7;read
        nop
        movf PORTB,w
        movwf indata
        rlf indata,f
        rlf indata,f
        rlf indata,f
        rlf indata,w
        andlw 0f0
        movwf indata
        bcf PORTB,5;bit 0-3 read
        nop
        movf PORTB,w
        andlw 0f
        iorwf indata,f
        bsf PORTB,6
        nop
        movf PORTB,w
        bsf PORTB,7;read end
        andlw 07;
        iorlw 10
        movwf FSR
        movf indata,w
        movwf INDF;---- 22/3=7us
        goto t1ms3
;
     end
;
ＰＩＣ１６Ｆ５７が表示データを受け取るのはリストの終わりのところ、ｄａｔａｒｅａｄです。
ＰＩＣは７セグメントＬＥＤをダイナミックドライブ表示するため、１ｍＳに一度セグメント表示データと表示桁データを出力します。
１ｍＳは命令を繰り返し実行することで作り出しています。
その繰り返しの中で１ｍＳに５１２回、ＲＢ４をチェックしています。
ＲＢ４はＥＰＭ７１２８ＳＬＣ８４につながっていて、その端子はＥＰＭ７１２８ＳＬＣ８４がＮＤ８０ＺモニタプログラムからのデータをラッチするとＬになります。
ＲＢ０〜ＲＢ３にはＥＰＭ７１２８ＳＬＣ８４から表示桁０〜７とセグメントデータの上位４ビットと下位４ビットが３回に分けて出力されます。
３回に分けて出力されるデータはＰＩＣ１６Ｆ５７がＲＢ５とＲＢ６で指定します。
ＲＢ５＝０、ＲＢ６＝０　セグメントデータ下位４ビット
ＲＢ５＝１、ＲＢ６＝０　セグメントデータ上位４ビット
ＲＢ５＝０、ＲＢ６＝１　表示桁アドレス（０〜７）
ＲＢ７＝０のときＰＩＣ１６Ｆ５７が読取動作中であることを示します。
このようにしたのはＰＩＣ１６Ｆ５７の少ないＩ／Ｏ端子で処理を可能にするための工夫です。
理解を助けるために、ＰＩＣ１６Ｆ５７周りの回路図を再掲します。

●ＥＰＭ７１２８ＳＬＣ８４＋ＰＩＣ１６Ｆ５７回路（７ＳＥＧＭＥＮＴ表示部分）

回路図の必要部分を再掲します。
今回は７セグメント表示回路部分のみです。
当初はＲＡ３も使うつもりだったのですがＲＢ０〜ＲＢ７だけで済んでしまったため、ＲＡ３は実際には使っていません。


●カメレオンロジアナの波形

下は上で説明したＰＩＣ１６Ｆ５７の動作（実際にはＮＤ８０ＺモニタとＥＰＭ７１２８ＳＬＣ８４の動作も連動しています）をカメレオンロジアナで観測した波形です。

ＰＲＯＢＥ００はＲＢ７、ＰＲＯＢＥ０１はＲＢ６、ＰＲＯＢＥ０２はＲＢ５、ＰＲＯＢＥ０４はＲＢ４です。
ＲＢ４入力がＬになるとＲＢ５＝Ｈ、ＲＢ６＝Ｌが出力されるとともにＲＢ７＝Ｌになります。
その後ＲＢ５＝０、ＲＢ６＝０になり、続いてＲＢ５＝０、ＲＢ６＝１になったあと、読み取りを終了した印としてＲＢ７＝Ｈになります。
ＲＢ４もＨになります。
これで１桁分のデータの送受が完了しました。

下はその０．５ｍＳ後の波形です。
次の１桁のデータが上と同じように送受されています。


ＣＰＬＤ入門！［第３９回］
２０１９．４．２８ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る