２０１９．６．１９
前へ
次へ
ホームページトップへ戻る

［新連載］ＣＰＬＤ入門！
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
いつか使うことになるだろうと思ってはいたのですが。
何を今頃になって、というようなものですが。
ようやく本気で、ＣＰＬＤと四つに取り組みます。
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜



［第７２回］


●ＶＨＤＬサンプルプログラム１　８２Ｃ５５（５）

前回はＡポート出力とＢポート出力について書きました。
今回はＣポート出力です。

●Ｃポート出力

前回と同様、前段と後段の２つに分けて考えます。
まずは前段です。
Ｃポートは上位４ビットと下位４ビットが分かれています。
両方が出力のときはＡポート、Ｂポートと同じ動作になりますが、片方が出力でもう片方が入力の場合もありますから、それを考慮したプログラムになります。
さらにＣポートにはビット出力モードがあるので、そのための記述も必要です。

-- portC out
process(IOW)
begin
        if IOW='0' then
                if ADRSIN="11110010" then
                        if chinout='0' then
                                pchout<=DINOUT(7 downto 4);
                        end if;
                        if clinout='0' then
                                pclout<=DINOUT(3 downto 0);
                        end if;
        -- bit out
                elsif ADRSIN="11110011" and DINOUT(7)='0' then
                        if clinout='0' then
                                if DINOUT(3 downto 1)="000" then
                                        pclout(0)<=DINOUT(0);
                                elsif DINOUT(3 downto 1)="001" then
                                        pclout(1)<=DINOUT(0);
                                elsif DINOUT(3 downto 1)="010" then
                                        pclout(2)<=DINOUT(0);
                                elsif DINOUT(3 downto 1)="011" then
                                        pclout(3)<=DINOUT(0);
                                end if;
                        end if;
                        if chinout='0' then
                                if DINOUT(3 downto 1)="100" then
                                        pchout(0)<=DINOUT(0);
                                elsif DINOUT(3 downto 1)="101" then
                                        pchout(1)<=DINOUT(0);
                                elsif DINOUT(3 downto 1)="110" then
                                        pchout(2)<=DINOUT(0);
                                elsif DINOUT(3 downto 1)="111" then
                                        pchout(3)<=DINOUT(0);
                                end if;
                        end if;
                end if;
        end if;
end process;

ｉｆ　ＡＤＲＳＩＮ＝”１１１１００１０”　ｔｈｅｎのところの記述はＡポート、Ｂポートと同じ考え方です。
ｃｈｉｎｏｕｔ、ｃｌｉｎｏｕｔにはそれぞれそれ以前に読み込まれたコントロールワードのＣポート上位４ビット、下位４ビットの向きを示す値が保持されています。
値が’０’なら出力、’１’なら入力です。
ＣＰＵからのＯＵＴ命令が出されたとき（ＩＯＷ＝’０’のとき）、Ｉ／ＯアドレスがＦ２ならばＣポートへの出力になります。
ポートの向きが出力なら、そのときのデータバスの上位４ビットの値がｐｃｈｏｕｔ、下位４ビットの値がｐｃｌｏｕｔに入ります。
ｐｃｈｏｕｔ、ｐｃｌｏｕｔに入れられた値は、次に同じことが発生するまでそれぞれラッチされています。

ＩＯＷ＝’０’でＡＤＲＳＩＮがＦ３のときはコントロールワード出力ですが、その値のビット７が’０’のときは、Ｃポートに対するビット出力コマンドになります（［第６８回］参照）。
ｅｌｓｉｆ　ＡＤＲＳＩＮ＝”１１１１００１１”　ａｎｄ　ＤＩＮＯＵＴ（７）＝’０’　ｔｈｅｎ　以下がそのための記述です。
Ｃポートの下位４ビットが出力モードに設定されているならば（ｃｌｉｎｏｕｔ＝’０’ならば）、ＤＩＮＯＵＴのビット３〜ビット１が”０００”〜”０１１”のときはＣポートの下位４ビットの出力データをラッチしているｐｃｌｏｕｔのビット０〜ビット３に、ＤＩＮＯＵＴのビット０の値が出力されます。
またＣポートの上位４ビットが出力モードに設定されているならば（ｃｈｉｎｏｕｔ＝’０’ならば）、ＤＩＮＯＵＴのビット３〜ビット１が”１００”〜”１１１”のときはＣポートの上位４ビットの出力データをラッチしているｐｃｈｏｕｔのビット４〜ビット７に、ＤＩＮＯＵＴのビット０の値が出力されます。

●ｅｌｓｉｆかｉｆか？

実は上のプログラムのｉｆ　ＡＤＲＳＩＮ＝”１１１１００１０”　ｔｈｅｎのところは、当初はＡポート、Ｂポートと一緒にして下のように書いていました。
この時点ではビット出力については後回しにしていたため、そのように記述できると考えたからです。

-- port out data from pc
process(IOW)
begin
        if IOW='0' then
                if ADRSIN="11110000" and ainout='0' then
                        paout<=DINOUT;
                elsif ADRSIN="11110001" and binout='0' then
                        pbout<=DINOUT;
                elsif ADRSIN="11110010" and chinout='0' then
                        pchout<=DINOUT(7 downto 4);
                elsif ADRSIN="11110010" and clinout='0' then
                        pclout<=DINOUT(3 downto 0);
                end if; 
        end if;
end process;

ところがこのプログラムをＥＰＭ７１２８ＳＬＣ８４に書き込んで、ＮＤ８０Ｚ３．５に接続してテストしてみると、Ａポート、Ｂポート、Ｃポートの上位４ビットからは正しくデータが出力されます。
しかしＣポートの下位４ビットだけは反応してくれません。
なぜだ？
最初は全く原因がわからず、あれこれあちこちをいじっていましたが、そのうち上のプログラムのＣポートの上位４ビットの記述と下位４ビットの記述を入れ替えたところ、今度は下位４ビットからは正しく出力が行なわれるようになったのですが、上位４ビットが反応なしになってしまいました。
記述順序が関係する？？？（その通りなのですが、この時点ではそのことがわかっていませんでした）
しかしＡポートとＢポートの記述順序を入れ替えても、特に問題は発生しません。
Ｃポートの上位と下位だけが、あとで記述した部分のみ実行されないように見えます。
なぜだああ？

上のリストをうなりながら眺めているうちに、やっと気が付きました。
わかったぞお！

●ｉｆ文にｅｌｓｉｆがついているときは要注意

ｉｆ文の次にｅｌｓｉｆが続くときは、上から順にｉｆ、ｅｌｓｉｆの条件が試されていきます。
上のプログラムでは最初にまずＡＤＲＳＩＮ＝”１１１１００００”　ａｎｄ　ａｉｎｏｕｔ＝’０’がチェックされます。
その結果が真のときは、ｅｌｓｉｆ以下の文は実行されません。
ｅｌｓｉｆはそれより前のｉｆ（またはｅｌｓｉｆ）を受けて、「そうではないならば」と続くｉｆ文です。
ですからそれよりも前のｉｆが真になってしまったら、それより後ろのｅｌｓｉｆは実行されない道理です。

もしもＡＤＲＳＩＮ＝”１１１１００００”　ａｎｄ　ａｉｎｏｕｔ＝’０’であったならば、最初のｉｆの結果が真になりますから、ｐａｏｕｔ＜＝ＤＩＮＯＵＴのみが実行されます。
もしもＡＤＲＳＩＮ＝”１１１１０００１”　ａｎｄ　ｂｉｎｏｕｔ＝’０’であったならば、最初のｉｆの結果は偽ですから、次のｅｌｓｉｆが試され、その結果ｐｂｏｕｔ＜＝ＤＩＮＯＵＴのみが実行されます。
もしもＡＤＲＳＩＮ＝”１１１１００１０”　ａｎｄ　ｃｈｉｎｏｕｔ＝’０’であったならば、最初のｉｆと次のｅｌｓｉｆの結果は偽ですから、その次のｅｌｓｉｆが試され、その結果ｐｃｈｏｕｔ＜＝ＤＩＮＯＵＴのみが実行されます。

さてここからが問題です。
もしもＡＤＲＳＩＮ＝”１１１１００１０”　ａｎｄ　ｃｌｉｎｏｕｔ＝’０’であったならば、同じように最後のｐｃｌｏｕｔ＜＝ＤＩＮＯＵＴが実行される、と考えたのですが、考えが足りませんでした。
ＡＤＲＳＩＮの値が同時にＦ０、Ｆ１、Ｆ２の値をとることはありません。
ですから上のプログラムは最後のｅｌｓｉｆ文以外はそれぞれ正しく機能します。

しかし最後のｅｌｓｉｆ文は？
もしもその上のＡＤＲＳＩＮ＝”１１１１００１０”　ａｎｄ　ｃｈｉｎｏｕｔ＝’０’が成立してしまうと、その次のｅｌｓｉｆ文は実行されません。
このことはＣポートの上位４ビットと下位４ビットがともに出力に設定されているときに起きてしまいます。
そういうことだったのでした。
このように同時に成立する複数の条件がある場合には、ｅｌｓｉｆでつなぐのではなくて、それぞれをｉｆ〜ｔｈｅｎ、ｅｎｄ　ｉｆ；を使って記述しなければなりません。
ということを体験を通じて学んでしまいました。
これは貴重な体験ではありますが、なかなかに苦い薬であります。

さて。
それでは本筋に戻ります。
下はＣポート出力の後段の記述です。

--portCL out
process(clinout,pclout)
begin
        if clinout='0' then
                PCL<=pclout;
        else
                PCL<="ZZZZ";
        end if;
end process;
--portCH out
process(chinout,pchout)
begin
        if chinout='0' then
                PCH<=pchout;
        else
                PCH<="ZZZZ";            
        end if;
end process;

ここは前回のＡポート、Ｂポートの後段のプログラムと同じです。
出力モードのとき（ｃｌｉｎｏｕｔ＝’０’のとき）はＰＣＬにｐｃｌｏｕｔが出力されます。
ｐｃｌｏｕｔは今回の最初のところでお見せしたプログラムでラッチされた出力データです。
ｅｌｓｅはその他のとき、つまりｃｌｉｎｏｕｔ＝’１’、入力モードのときを指しています。
そのときはＰＣＬ出力はハイインピーダンスになります。
センシビリティリスト（ｐｒｏｃｅｓｓ文の（　）の中）はｃｌｉｎｏｕｔとｐｃｌｏｕｔしか記述していませんから、ｂｅｇｉｎ以下の文はｃｌｉｎｏｕｔの値が変化したときか、ｐｃｌｏｕｔの値が変化したとき以外は実行されません。
以上はＰＣＬについての説明ですが、ＰＣＨについても全く同様です。

今回もしっかり疲れてしまいました。
今回は、ここまでにいたします。

ＣＰＬＤ入門！［第７２回］
２０１９．６．１９ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る