２０１３．１２．２８
前へ
次へ
ホームページトップへ戻る

復活！ＣＰ／Ｍ　ワンボードマイコンでＣＰ／Ｍを！
ＣＰ／ＭがＴＫ－８０互換のワンボードマイコンの上で復活します
ＮＤ８０ＺⅢとＭＹＣＰＵ８０の上でＣＰ／Ｍが走ります！

［第５３１回］


●ＰＩＣサンプルプログラムの説明（割込みルーチン）

また間が２日空いてしまいました。
この２週間ほどは、ちょっと必要がありまして、私としては全く未経験の新しいことに首をつっこんでしまいましたので、なかなかホームページの更新のために時間を割くことができませんでした。
やっとめどが少しついたと思ったら、もう年の暮れも押し迫ってきてしまいました。
その新しいことにつきましては、年が明けたあたりからまたご説明することになろうかと思います。
その前に、書きかけのＰＩＣプログラムの説明を片付けてしまわなければなりません。

今回は割込みプログラムの本体について簡単に説明をいたします。
下が割込みプログラムの本体です。
サンプルプログラムの全体のリストは［第５１６回］にあります。

;
        org 300
;
int
     movwf savew
     swapf STATUS,w
        clrf STATUS
     movwf savests
;
     bcf STATUS,5;bank 0
        movlw 1
        xorwf PORTE,f;pulse out
        bcf T1CON,0;stop T1
        movf t1Hdata,w
        movwf TMR1H
        movf t1Ldata,w
        movwf TMR1L
        movlw 1
        movwf T1CON;start T1
intend
        clrf PIR1;***************
     swapf savests,w
     movwf STATUS
     swapf savew,f
         swapf savew,w
     retfie
;


割込みプログラムはアドレス３００Ｈに置いてあります。
別にこのようにしなければならない理由はありません。
メインプログラムの前に置いても、途中に置いても構いません。
それではなぜ３００Ｈに置いたかといいますと、このあと説明をする予定のテーブルアクセスとのからみで、上位８ビットが００ではないアドレスに割込みプログラムを置いた場合に、何か特別の操作が必要かどうかを確かめるためにそのようにしてみたのです。
結果から言えば、そのようにしても全く問題はありませんでした。
しかしそれはあくまでメインプログラムと同じページ内（２ＫＢ）にあれば、という前提でのお話です。
ページについては［第５１４回］で説明をしました。
ま、しかし、それについて追求を始めますとまた終わらなくなってしまいます。
ですのでそれについては置いておくことにいたします。
お話を元に戻しまして、テーブル参照ではアドレスの上位８ビットに注意が必要である、ということについて少し［第５１４回］で触れています。
しかし上に書きましたように、割込みプログラムについてはメインプログラムと同じページ内にあるのならば、特にそれを意識する必要はありません。
ただどこに割り込みプログラムを置いても、割込みプログラムへのｇｏｔｏ文を必ず４番地に書いておかなければいけません。

;
     org 0
st0
     goto start
;
     org 04
        goto int
;
        org 05
;
start


さてそれでは、割込みプログラムの説明です。
ＰＩＣの割込みプログラムでは決ったルールがあります。
下がその先頭の部分です。
割込みプログラムを正しく実行させるためには、このように書いておかなければなりません。

;
int
     movwf savew
     swapf STATUS,w
        clrf STATUS
     movwf savests
;


ｃｌｒｆ　ＳＴＡＴＵＳは必須ではありません。
これは必要があればこうするというだけです。
しかし割込みが発生した時点ではどのレジスタバンクが有効になっているかわからないので、大抵はＳＴＡＴＵＳに値を与えて必要なレジスタバンクにアクセスすることになると思います。
ｃｌｒｆ　ＳＴＡＴＵＳ　の実行によってレジスタバンク０がセレクトされます。
ｍｏｖｗｆ　ｓａｖｅｗ
ｓｗａｐｆ　ＳＴＡＴＵＳ，ｗ
と
ｍｏｖｗｆ　ｓａｖｅｓｔｓ
は必須です。
これは割込み発生直前のｗレジスタとＳＴＡＴＵＳの値を保存しておくためです。
ちょいと変わった書き方ですが、おまじないだと思ってください（そのわけは後ほど説明します）。
ｓａｖｅｗとｓａｖｅｓｔｓはユーザーレジスタです。この名前ではなくてもどんな名前でもいいのですが、置く場所には約束事があります。
ＰＩＣ１６Ｆ８８７の場合、ｗレジスタとＳＴＡＴＵＳレジスタを保存しておくためのユーザーレジスタは、アドレス７０Ｈ～７ＦＨに置く必要があります。
このアドレスはバンク０～バンク３まで共通にアクセスできるアドレスです（［第５２０回］参照）。
そのようにしておかないと、割り込みが発生した直後にはどのバンクが有効になっているか分からないので、ｍｏｖｗｆ　ｓａｖｅｗが正しく実行されません。

;
savew equ 70
savests equ 71
;


このようにして保存したｗレジスタとＳＴＡＴＵＳレジスタは、割込みプログラムを終わるときに、これもまた決った書き方で元の値に戻します。

intend
     clrf PIR1;***************
     swapf savests,w
     movwf STATUS
     swapf savew,f
     swapf savew,w
     retfie
;


ｓｗａｐｆ　ｓａｖｅｓｔｓ，ｗからｓｗａｐｆ　ｓａｖｅｗ，ｗまでがその部分です。
なぜこのようなややこしい書き方をするかと言いますと、ｍｏｖｆ命令を使うとフラグが変化してしまうからです。
それを防ぐためにｓｗａｐｆ命令を使います。
ｍｏｖｗｆ命令，ｓｗａｐｆ命令はフラグを変化させません。


［出典］Ｍｉｃｒｏｃｈｉｐ　Ｔｅｃｈｎｏｌｏｇｙ　Ｉｎｃ．　ＰＩＣ１６Ｆ８８２～８８７Ｄａｔａ　Ｓｈｅｅｔ

最後のｒｅｔｆｉｅは割込みプログラムからメインプログラムに戻るためのリターン命令です。

ｃｌｒｆ　ＰＩＲ１に＊＊＊＊がつけてありますが、そもそもこのお話を書くことにした理由の１つがこの命令でした。
これは必ず書かなければならない命令だったのですが、うっかりして書き忘れてしまったために、プログラムが期待した通りに実行されずに、かなり悩んでしまいました。
この命令は必須です。
忘れないように注意いたしましょう。

最後は割込み処理の本体です。
ここは個々の処理によってそれぞれ必要なことを書きます。

;
     bcf STATUS,5;bank 0
        movlw 1
        xorwf PORTE,f;pulse out
        bcf T1CON,0;stop T1
        movf t1Hdata,w
        movwf TMR1H
        movf t1Ldata,w
        movwf TMR1L
        movlw 1
        movwf T1CON;start T1


今、気が付きました。
この上のところで　ｃｌｒｆ　ＳＴＡＴＵＳ　を実行していますから、ｂｃｆ　ＳＴＡＴＵＳ，５　は全く無駄な命令でした。
ｃｌｒｆ　ＳＴＡＴＵＳ　によって、すでにバンク０がセレクトされています。

もうあと少しのところだったのですが、時間がなくなってしまいました。
この続きは次回にいたします。

ワンボードマイコンでＣＰ／Ｍを！［第５３１回］
２０１３．１２．２８ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る