ＴＴＬでＣＰＵを作ろう！

~~標準ＴＴＬ~~だけ（！）でCPUをつくろう！（組立てキットです！）
(ホントは７４ＨＣ、ＣＭＯＳなんだけど…）
［第２５１回］

●ＴＫ８０のモニタプログラム（スタートルーチン）の説明です

前々回から、ＴＫ８０のステップ動作を、ソフトウェアの面から説明しています。
前回の説明で、ステップ動作でＲＳＴ７割込みを受けて、０１５１からの「ブレイク」処理ルーチンが実行されることをお話しました。
そのプログラムの最後は、００５１からの、モニタスタートルーチンへのＪＭＰ命令で終わっていました。

あれ？
割込みプログラムの最後は、
ＥＩ
ＲＥＴ
だったはずですが、どうしてこんなところに来てしまうのでしょう？

普通の割込みプログラムならば、最後はＥＩ、ＲＥＴになるのですけれど、ステップ動作は、ちょいと普通の割込みプログラムとは異なっているのです。

割込みを利用してはいますけれど、ステップ動作の処理ルーチンは、実は「ブレイク」ルーチンなのだ、ということを前回書きました。
「ブレイク」ですから、モニタプログラムに戻って、そのあとは通常の「モニタモード」になるのです。
ステップ動作（ブレイク動作）でモニタプログラムに戻ったあとは、たとえばメモリにセーブされたレジスタの値を確認したりできるように、普通のキー操作が行えることが求められます。

ですから、普通のキー操作をする、モニタスタートルーチンにジャンプするようにしてあるのです。
それなら、ステップ動作の続きはどうなるの？
という疑問が出てきます。

その答えはじきにわかります。
まずはモニタスタートルーチンを見てみることにしましょう。


              ;
              ; MONITOR START
              ;
0051 3EF7     START:MVI A,F7
0053 D398       OUT 98;PIC reset
0055 31D1FF     LXI SP,MONSP
0058 CDC001     CALL SEGCG
005B CD1602     CALL KEYIN
005E 47         MOV B,A
005F E610       ANI 10
0061 CA8400     JZ DIGIT
0064 78         MOV A,B
0065 E60F       ANI 0F
0067 0600       MVI B,00
0069 87         ADD A
006A 4F         MOV C,A
006B 217400     LXI H,TABL
006E 09         DAD B
006F 7E         MOV A,M
0070 23         INX H
0071 66         MOV H,M
0072 6F         MOV L,A
0073 E9         PCHL
              ;
0074 CC00     TABL:DW GOTO
0076 F901       DW RESRG
0078 9400       DW ADSET
007A B800       DW ADDCX
007C 9D00       DW ADINX
007E C200       DW MEMW
0080 D500       DW SDATA
0082 0701       DW LDATA
              ;
0084 CDB501   DIGIT:CALL SHIFT
0087 3AECFF     LDA DATA
008A B0         ORA B
008B 32ECFF     STA DATA
008E CDA101     CALL RGDSP
0091 C35100     JMP START

００５１からのモニタスタートルーチンは、その名の通り、モニタプログラムが００００から実行を開始すると、必要な初期設定を済ませたあと、必ずここからスタートします。
何をしているかと言いますと、ここではキーが押されるのを待っているのです。
００５ＢのＣＡＬＬ　ＫＥＹＩＮがキー入力ルーチンです。

ＫＥＹＩＮは０２１６番地にあるサブルーチンです。
キーが押されるまで待っています。
キーが押されると、そのキーに対応する「キーコード」をＡレジスタに入れてリターンしてきます。

参考までに、キーコードとキーの対応表を下に示します。

●ＴＫ８０のキーコード表

キーコード	キー
００	０
０１	１
０２	２
０３	３
０４	４
０５	５
０６	６
０７	７
０８	８
０９	９
０Ａ	Ａ
０Ｂ	Ｂ
０Ｃ	Ｃ
０Ｄ	Ｄ
０Ｅ	Ｅ
０Ｆ	Ｆ
１０	ＲＵＮ
１１	ＲＥＴ
１２	ADRSSET
１３	READ DECR
１４	READ INCR
１５	WRITE INCR
１６	STOREDATA
１７	LOADDATA

●数字入力処理

０～Ｆの数字キーのコードは、「そのまんま」です。
入力されたキーに対応するキーコードが００～０Ｆのとき（つまりビット４が１ではないとき、というチェックを００５ＦのＡＮＩ　１０で行っています）、００８４のＤＩＧＩＴへジャンプします。

余り詳しく説明していますと、なかなか先へ進めませんから、簡単に説明をします。
ここではＬＥＤの右４桁の「データ表示部」に表示するためのデータを保持しているＦＦＥＣ、ＦＦＥＤの値を、まず左に４ビットシフトして（ＣＡＬＬ　ＳＨＩＦＴ）、空いた最下位４ビットに、今入力された数値コードの４ビットを加えます（ＯＲ　Ｂ）。
そして更新された表示データを、ＬＥＤに表示するためにＲＧＤＳＰサブルーチンをＣＡＬＬしてから、またキー入力処理に戻ります（ＪＭＰ　ＳＴＡＲＴ）。

●命令キーの入力処理

キーコードが１０～１７のときは、それぞれの処理ルーチンにジャンプします。
キーコードは数字キーのチェックでＡＮＩを使うためにＢレジスタに退避されています。
そのＢレジスタの値を、ＣＭＰ命令で比較しながら、ＪＺでそれぞれの処理ルーチンへジャンプする、というプログラムでもいけないことはないのですが、それではいかにも「稚拙」です。

今回のようにコードが序数（順に並んだ数）であるような場合には、テーブルを使います。
これもよく使われるテクニックです。

まず各命令へのＪＭＰ先アドレスのテーブル（表）データを用意します。
００７４～００８３が命令ジャンプテーブルです。
たとえば最初の００７４、００７５にあるＣＣ００はＲＵＮキーの処理ルーチンへのジャンプアドレスです。
ＲＵＮキーの処理プログラムは００ＣＣにありますが、アドレスの上位と下位が入れ替わる形になっています。
こうしなければいけないことはないのですが、８０８０の命令のルールでアドレスなど２バイトの値をメモリに格納するときは、下位バイト、上位バイトの順に格納するので、ここでもそういう配置になっているのだと思います。

その次の００７６、００７７にあるＦ９０１はＲＥＴキーの処理ルーチンへのジャンプアドレスです。
ここも上位と下位が逆になっています。
ＲＥＴキーの処理プログラムは０１Ｆ９から始まります。

なおニーモニックのＤＷ（ｄｅｆｉｎｅ　ｗｏｒｄ）はＤＢ（ｄｅｆｉｎｅ　ｂｙｔｅ）と同じように、もともとのＣＰＵの命令ではなくて、アセンブラ処理のために用意された「擬似命令」です。
ＤＢは１バイトのコードをそのまま記述するときに使います。
これに対してＤＷは２バイトのデータを直接定義するときに用いられます。

さて、命令コードをもとに、テーブルを参照して、それぞれの処理ルーチンへジャンプするためのプログラムは、００６４からの部分です。


0064 78         MOV A,B
0065 E60F       ANI 0F
0067 0600       MVI B,00
0069 87         ADD A
006A 4F         MOV C,A

Ｂレジスタに退避させてあったキーコードの上位４ビットを０にして、００～０７にします。
ＡＤＤ　Ａでその２倍、００～０Ｅにしたあと、それをＣレジスタに入れます。
Ｂレジスタは００にします。
キーコードの１０～１７をもとにして、ＢＣレジスタに００００～０００Ｅが入りました。


006B 217400     LXI H,TABL
006E 09         DAD B

ＨＬレジスタにテーブルトップのアドレス００７４を入れて、ＤＡＤ　Ｂを実行すると、その結果ＨＬレジスタは、キーコードに対応するジャンプテーブルのアドレスを示すことになります。


006F 7E         MOV A,M
0070 23         INX H
0071 66         MOV H,M
0072 6F         MOV L,A
0073 E9         PCHL

最後の仕上げです。
ＨＬレジスタは目的とするジャンプ先アドレスの下位アドレスがあるテーブル番地を示しています。
ＭＯＶ　Ａ，Ｍで、そのジャンプ先の下位アドレスがＡレジスタに入れられます。
ＩＮＸ　Ｈ
ＭＯＶ　Ｈ，Ｍ
で、ジャンプ先の上位アドレスがＨレジスタに入ります。
そしてＡレジスタに入れられていたジャンプ先の下位アドレスを、ＭＯＶ　Ｌ，ＡでＬレジスタに入れます。

ここで、最初にいきなりＭＯＶ　Ｌ，Ｍとやってしまうと、ＨＬレジスタがジャンプテーブルを示していたのが、別の値に変化してしまって、次のＭＯＶ　Ｈ，Ｍが正しく実行できません。
下位バイトを読み出すのにＭＯＶ　Ａ，Ｍとしているのは、その理由からです。
そして、最後にＰＣＨＬを実行します。
ＰＣＨＬはＨＬの値をプログラムカウンタにセットする命令ですから、このＰＣＨＬを実行することで、ジャンプテーブルが示すジャンプ先へジャンプすることになります。

●ＲＥＴキーの動作の説明です

やっと、ここまでたどりつきました。
ステップ動作の締めくくりです。

ＲＥＴキーはステップ動作を再開するためのキーです。
ＲＳＴ７割込みによって、ブレイクしてモニタプログラムに戻ったあとは、普通にキー操作ができるようにするために、モニタスタートルーチンに行きました。

このままステップ動作を止めてしまうこともできます。
でも、もしステップ動作を続けるのならば、ＲＥＴキーを押します。
ＲＥＴキーを押すと、メモリに保存してあったブレイク直後のＣＰＵレジスタやプログラムカウンタの値などを、元通りに戻したあと、ユーザープログラムに戻ります。

ちょっと考えると、どうするとそんな器用なことができるのだろう、と思いますが、そこでもテクニックが使われています。


              ;
              ; REGISTER RESTORE
              ;
01F9 2AE2FF   RESRG:LHLD SSAVE
01FC F9         SPHL
01FD 2AE0FF     LHLD PSAVE
0200 E5         PUSH H
0201 2AE4FF     LHLD LSAVE
0204 E5         PUSH H
0205 2AEAFF     LHLD FSAVE
0208 E5         PUSH H
0209 2AE8FF     LHLD CSAVE
020C 4D         MOV C,L
020D 44         MOV B,H
020E 2AE6FF     LHLD ESAVE
0211 EB         XCHG
0212 F1         POP PSW
0213 E1         POP H
0214 FB         EI
0215 C9         RET

これもまたみごとな職人芸のようなプログラムです。
ＳＳＡＶＥはブレイクしたときに、スタックポインタを保存したメモリアドレスです。
同様に、ＰＳＡＶＥはプログラムカウンタ、ＬＳＡＶＥはＨＬレジスタ、ＦＳＡＶＥはＡレジスタとフラグレジスタ、ＣＳＡＶＥはＢＣレジスタ、ＥＳＡＶＥはＤＥレジスタをそれぞれ格納したメモリアドレスです。

最初に
LHLD SSAVE SPHL
でスタックポインタにもとの値を戻します。
これは、まあ、わかりますね。

次の
LHLD PSAVE PUSH H
になると、ええっ？なにをしているのだろう？
と思ってしまいますが、これは最後に利いてきます。
ＰＳＡＶＥには、ステップ動作でモニタプログラムに戻ったときに、次に実行するはずだったユーザープログラムのアドレス、つまりそのときのプログラムカウンタの値がセーブされています。
そのアドレスをＰＵＳＨ　Ｈでスタックに保存します。

その次の
LHLD LSAVE PUSH H LHLD FSAVE PUSH H
は、ＨＬレジスタと、Ａレジスタおよびフラグレジスタをもとにもどしてからスタックに保存しています。
フラグレジスタは、こうしておいて、後でＰＯＰ　ＰＳＷ命令を使わなければもとにもどせませんから、ここでＰＵＳＨするのは理にかなっています。
しかしＨＬレジスタについては、はてな？です。

ここでメモリから読み込まなくても、最後に読み込めばよいはずです。
つまり、ここで
LHLD LSAVE PUSH H
としないで、最後の
POP H
の代わりに、
LHLD LSAVEを実行すれば、むだな
PUSH H POP Hを省くことができます。

それはともかくとして、次はＢＣレジスタとＤＥレジスタの復帰です。
LHLD CSAVE MOV C,L MOV B,H LHLD ESAVE XCHG
これは、わかりますよね。

最後に、
EI RET
を実行すると、割り込みが許可されて、それからＲＥＴ命令によって、最初にスタックにＰＵＳＨしたユーザープログラムのアドレスがプログラムカウンタに戻されて、そしてユーザープログラムにリターンします。

いやあ、やっと、ステップ動作の説明が終わりました。
ながながと、モニタプログラムの説明を続けてきたのにはわけがあります。
それは、このあとにお話をする予定の、「とんでもないミスを見つけてしまった」というところのお話で、いままで説明してきたことを予備知識として理解しておいていただいたほうが、話を進め易いかなぁ、と思ったからです。
２００９．６．１６ｕｐｌｏａｄ

前へ
 次へ
 ホームページトップへ戻る