標準ＴＴＬだけ（！）でCPUをつくろう！（組立てキットです！）
(ホントは７４ＨＣ、ＣＭＯＳなんだけど…）
［第５２０回］

●ＰＩＣ１８Ｆ１４Ｋ５０メモリマップ

ＰＩＣ１８Ｆのほとんどの機械語の命令は８ビットのメモリアドレスしかアクセスできません。
８ビットのメモリアドレスは００〜ＦＦの２５６バイトです。
しかしＰＩＣ１８Ｆ１４Ｋ５０には約１ＫＢのデータメモリがあります。

ＰＩＣ１８Ｆ１４Ｋ５０のメモリマップです。

［出典］ＭＩＣＲＯＣＨＩＰ社ＰＩＣ１８Ｆ１４Ｋ５０ＤａｔａＳｈｅｅｔ

前回も説明しましたように、８ビットのアドレスしかアクセスできない機械語命令で２５６バイトを超える範囲のメモリをアクセスするためのひとつの方法としてバンク切り換えがあります。
先頭から２５６バイトごとに分割して、それをＢａｎｋ０、Ｂａｎｋ１、…、Ｂａｎｋ１５とします。
必要な範囲のメモリをアクセスする前にバンクレジスタ（ＢＳＲ）に、そのバンク�ｂ�セットしておいてから、そのメモリアドレスをアクセスする命令を実行します。

しかしこの方法はプログラムによっては頻繁にＢＳＲにバンク�ｂ�書き込まなくてはならないことになって、なかなかに面倒です。
そこで、ユーザーが汎用のワークエリアとして最も良く使用するバンク０（アドレス０００〜０ＦＦ）の前半の９６バイト（０００〜０５Ｆ）と、システムレジスタ群があるバンク１５の１６０バイト（Ｆ６０〜ＦＦＦ）をくっつけた形でアクセスできるモードが用意されています。
その仮想的なバンクをＡｃｃｅｓｓ　Ｂａｎｋといいます（上図参照）。

Ａｃｃｅｓｓ　Ｂａｎｋを指定して、普通の機械語の命令で００〜ＦＦのメモリ範囲をアクセスすると、００〜５Ｆのアドレスを指定したときは、０００〜０５Ｆの範囲のメモリがアクセスされ、６０〜ＦＦのメモリ範囲をアクセスすると、Ｆ６０〜ＦＦＦの範囲のメモリがアクセスされます。

ＰＩＣ１８Ｆの命令はアセンブラ表記で’ａ’パラメータに０を指定したときに、Ａｃｃｅｓｓ　Ｂａｎｋが選択されます。
前回はちょいとうっかりして、’ａ’パラメータを省略すると（デフォルトでは）、Ａｃｃｅｓｓ　Ｂａｎｋが選択される、と書きましたが、正しくはデフォルトではＢＳＲが選択される、でした（ＤａｔａＳｈｅｅｔを読みますとそのようにしか解釈できないものですから、一旦はこう書いたのでしたが…。下記の［注記］をお読みください）

［２０１０．６．１４注記］
なにしろいろいろあれもこれもと、足りない頭と足りない時間でフルに活動しておりますものですから、一旦はそのように書いたのですけれど、どうにもおかしい。
そーいうことではないはずなのだが…。
なんだか過去の経験を無理やり否定されてしまったような気持ち悪さを感じながら、まま、ＤａｔａＳｈｅｅｔにはそのように書いてあるのだから、ということで、抵抗する頭を無理やり納得させたのでありましたが…。
やっぱり納得できません。
そりゃあ、おかしいよお。
どうにも納得できませんでしたので、作業が一息つきましたときに、あらためて確認をしてみました。
その結果、やっぱり、ということで納得いたしました。
納得しました結果からしますと、今回、ここで書きました’ａ’パラメータにつきましての記述は、やっぱりおかしい書き方になってしまっておりました。
’ａ’パラメータのｄｅｆａｕｌｔにつきましては、［第５２３回］にまとめましたので、ご参照願います。
（注記ここまで）

’ａ’パラメータを省略するとＢＳＲをベースにしたバンク切り替えが指定されるのですが、ＦＳＲとして登録されているレジスタ名（ＰＯＲＴＡとかＴＲＩＳＡなど）を使った場合には、’ａ’パラメータを省略しても、アセンブラがＡｃｃｅｓｓ　Ｂａｎｋを指定するように翻訳してくれます。
ここらあたりのことにつきましては、［第４１２回］、［第４１３回］で説明をしています。

前回、ＰＩＣ１８Ｆ１４Ｋ５０でこのアクセス方法を使ったために、ドツボにはまってしまいました、と書きました。
むむむ。
全然、気が付かなかったのですよお。
上のメモリマップをよく見ますと、ＳＦＲ（Ｓｐｅｃｉａｌ　Ｆｕｎｃｔｉｏｎ　Ｒｅｇｉｓｔｅｒｓ）が破線で２つに分かれているのですよねえ。
アドレスＦ５３〜Ｆ５ＦとＦ６０〜ＦＦＦの２つに。
そしてＦ５３〜Ｆ５Ｆの方には（１）がついていて、図の下部を見ますと。

Ｎｏｔｅ１：　ＳＦＲｓ　ｏｃｃｕｐｙｉｎｇ　Ｆ５３ｈ　ｔｏ　Ｆ５Ｆｈ　ａｄｄｒｅｓｓ　ｓｐａｃｅ　ａｒｅ　ｎｏｔ　ｉｎ　ｔｈｅ　ｖｉｒｔｕａｌ　ｂａｎｋ

って書いてあります。
なるほど。
ここに気が付かなかった私が悪い。

しかし、しかし。
こおいうことは、できれば、やめていただきたい。
せっかくＡＣＣＥＳＳ　ＢＡＮＫなどというアクセス方法を用意しておいて、それでアクセスできないところにシステムレジスタを拡張してしまうってのは、ねえ。

●ＰＩＣ１８Ｆ１４Ｋ５０のＦＳＲ（Ｓｐｅｃｉａｌ　Ｆｕｎｃｔｉｏｎ　Ｒｅｇｉｓｔｅｒｓ）


［出典］ＭＩＣＲＯＣＨＩＰ社ＰＩＣ１８Ｆ１４Ｋ５０ＤａｔａＳｈｅｅｔ

おお。
気が付いてみれば、なんとしっかりはみ出しているではありませんかあ。
しっ、しかも、ＵＳＢ関連のレジスタの大半がしっかりはみ出していますう。
これじゃ、いくらやってもＵＳＢにアクセスできないはずだわ。

はい。これが［第５１３回］でお見せしたＰＩＣ１８Ｆ１４Ｋ５０の「動いてくれなかった」プログラムです。

;;;pic p18f14k50  USB test program
;10/6/2
;
	#include<p18f14k50.inc>
;cpuclock=48MHz exclock=12MHz
;
	CONFIG FOSC = ECH,CPUDIV = NOCLKDIV,USBDIV = OFF,PCLKEN = ON,PLLEN = ON,WDTEN=OFF,LVP=OFF
;
w=0
f=1
c=0
z=2
;
cntr0=0c
cntr2=0d
cntr1=20
;
	org 00
	clrf ANSEL
	clrf ANSELH
	clrf TRISC
	clrf TRISB
	clrf TRISA
;
usbreset
	movlw 16
	movwf UEP0　←ここが問題！！
	movlw 15;ping-pong buffer set for EP0(out) only	
	movwf UCFG
;
	call setbd0
;
	movlw 0ff
	movwf PORTC
	movlw 48
	movwf UCON;clear bit4,for SIE enbl
loop_ucon
	btfss UCON,4;if SETUP detect
	goto loop_ucon
;
loop
	call t1ms
	decfsz cntr1
	goto loop
	movlw 1
	xorwf PORTC
	goto loop	
;
;ep0 out data0(even)
setbd0
	lfsr 1,203
	movlw 05;address high
	movwf POSTDEC1
	movlw 00;address low
	movwf POSTDEC1
	movlw 08;bytes
	movwf POSTDEC1
	movlw 80;STAS(even)
	movwf POSTDEC1
	return
;
;1msec timer
t1ms
	movlw 0a;=10	
	movwf cntr2
t1ms2
	call tm100micros
	decfsz cntr2
	goto t1ms2
	return
;
tm100micros
	movlw 0f0;=240
	movwf cntr0
tm100micros2
	nop
	nop
	decfsz cntr0
	goto tm100micros2
	return
;
	end

ＵＥＰ０に１６を入れたつもりだったのですけれど、ＰＩＣ１８Ｆ１４Ｋ５０用としてこのプログラムをアセンブルしますと、ＵＥＰ０＝５３ｈとして機械語に翻訳されてしまいます。
すると、ＡＣＣＥＳＳ　ＢＡＮＫのルールで、この部分はＦ５３ｈではなくて、０５３ｈに１６をｍｏｖｅするという命令になってしまいます。

あ。もう少し、ですけれど、本日もまたタイムアウトになってしまいました。
ですので、この続きは次回に書くことにいたします。
２０１０．６．９ｕｐｌｏａｄ
２０１０．６．１４注記

前へ
次へ
ホームページトップへ戻る