標準ＴＴＬだけ（！）でCPUをつくろう！（組立てキットです！）
(ホントは７４ＨＣ、ＣＭＯＳなんだけど…）
［第５５９回］
●電子オルガンプログラム
前回は８０８０アセンブラの実行例として、電子オルガンプログラムをアセンブルしてみました。
ＮＤ８０ＺⅢのキーを押すとそのキーに割り当てられた高さの音がスピーカーから出力される、というプログラムです。
このプログラムは、以前にどこかで紹介したことがあるような気がして捜してみましたら、［第３６３回］にありました。
ＭＹＣＰＵ８０の操作説明書の内容紹介のところです。
キーと音の高さの対応図もありますので、そちらのページも参照してみてください。
プログラムリストもそこに掲載してあります。
前回紹介しました電子オルガンプログラムとほとんど同じものですが、ＣＰＵクロックが異なっているために、その部分は違っています。
ＭＹＣＰＵ８０のＣＰＵクロックは２ＭＨｚで、命令の実行クロック数もオリジナルの８０８０とは異なっています。
今回のＮＤ８０ＺⅢのＣＰＵクロックは６ＭＨｚですし、ＣＰＵはＺ８０ですから、やはり命令によってクロック数は８０８０と違っているものもあります。
ただ今回紹介しました電子オルガンプログラムは、初心者の方の参考にもなるように、と考えて、ソースプログラムは、命令数の少ない８０８０用のプログラムとして、８０８０ニーモニック（インテルニーモニック）で書きました。
Ｚ８０は８０８０の命令をマシン語レベルでは８０８０と全く同じように実行しますから、ソースプログラムの命令を８０８０のニーモニックで書いても全く問題はありません。
あ。もちろん８０８０ニーモニックで書いたソースプログラムは８０８０アセンブラでなければ、マシン語コードに翻訳することはできません。
同様にＺ８０ニーモニック（ザイログニーモニック）で書いたソースプログラムはＺ８０アセンブラでなければ、マシン語に翻訳することはできません。
しかしどちらの手続きによっても、アセンブルされてマシン語に翻訳された結果は同じものになります。
もっともＺ８０にはあるけれども８０８０にはない命令もたくさんありますから、そのような命令はＺ８０アセンブラでなければマシン語に翻訳することはできません。
ＮＤ８０ＺⅢはマシン語やアセンブラを勉強中の方にもぜひ使っていただきたい、と思っております。
そう思って、あらためて［第３６３回］も読み直してみたのですけれど、プログラムリストと、プログラムの動作の説明がしてあるだけで、プログラムそのものの説明はないようです。
まあ。めちゃめちゃ忙しかったんですものねえ。
でも、せっかくサンプルとして電子オルガンのプログラムリストをお見せしたことですから、この機会にプログラムそのものの説明をしてみたいと思います。
とっても簡単なプログラムですから、どなたもご理解いただけることと思います。
あ。
そういえば、突然に思い出しました。
●８０８０アセンブラ注記
前回は、そのもうひとつ前の回でＮＤ８０ＺⅢとＤＯＳ／ＶパソコンをＵＳＢで接続して、ＤＯＳ窓上のリモートプログラムを実行して、ＮＤ８０ＺⅢのキー入力の代わりに、パソコンのキーから入力して、ＮＤ８０ＺⅢをリモート操作する、という説明をしたあとで、突然８０８０アセンブラの説明を割り込んではじめてしまいました。
今回もまだその続きで、またもや脱線したまま走っております。
リモートプログラムの実行も、８０８０アセンブラの実行も、同じＤＯＳ窓（ＤＯＳプロンプト）の中で行いますし、その前の回のリモートプログラムの説明の次にいきなり８０８０アセンブラの話になってしまったものですから、ひょっとすると、お読みいただいている方のなかには、８０８０アセンブラもＵＳＢで接続したＮＤ８０ＺⅢが実行しているのではないか、と誤解された方もみえるかもしれません。
同じＤＯＳプロンプトで実行しますけれど、８０８０アセンブラはＤＯＳ／Ｖパソコンの上だけで動作します。
８０８０アセンブラは８０８６の命令で書かれたプログラムです（８０８０の命令ではありません）。
うーん。ややこしーい。
８０８０アセンブラは、その実行によって、８０８０のマシン語コードファイルを生成しますが、その生成の過程では、ＮＤ８０ＺⅢの接続を全く必要としません。
８０８０アセンブラを使うときには、ＮＤ８０ＺⅢをＵＳＢから切り離しておいても全く構いません。
●電子オルガンプログラムの説明
さて、では前回もお見せしましたｓｏｕｎｄ６．ｌｓｔを少しずつ切り分けながら説明をしていくことにいたします。
2010/7/20 21:25 sound6.txt
END=8056
;;;SOUND6.TXT
;;; sound for ND80Z3 clock=6MHz
;;; 10/3/18 10/6/15 7/20
;;;
ORG $8000
;
KEY=$0247
;
8000 CD4702 SND:CALL KEY
8003 3C INR A
8004 CA0080 JZ SND
8007 3D DCR A
8008 CD0E80 CALL SNDSB
800B C30080 JMP SND
プログラムの本体、メインプログラムはこれだけです。
非常に簡単です。
ＴＫ８０モニタプログラムのキー入力サブルーチンＫＥＹをＣＡＬＬしています。
ＴＫ８０のアプリケーションプログラムでは、このようにハードウェアに密接につながるところでは、モニタプログラムのサブルーチンをＣＡＬＬすることが一般的です。
ＴＫ８０に限らず、パソコンでも考え方は同じで、そのようにすることで、ハードウェアの底辺の面倒な処理をいちいちプログラムしなくても済むようになり、プログラムの作成が比較的容易になります。
もっともそのためには、モニタサブルーチンの機能や動作について一通りは理解しておくことが求められます。
ここではＣＡＬＬ ＫＥＹのあと、ＩＮＲ Ａを実行して、結果が０のときは、また８０００に戻ってＣＡＬＬ ＫＥＹを実行します。
何をやっているのでしょうか？
じつは、ここでキー入力の有無をチェックしているのです。
ＫＥＹサブルーチンはキーが押されていれば、そのキーに対応する数値（００～１７）をＡレジスタに入れてリターンします。
キーが押されていなければ、ＦＦを入れてリターンします。
INR Ａ（Ａレジスタを＋１加算する）の実行の結果、Ｚ（ゼロフラグ）が立つのは、加算前の値がＦＦのときだけです。
ですから、ＩＮＲ Ａを実行してＺフラグが立ったときは、Ａの値がＦＦのとき、つまりキーが押されていないときですから、なにもしないで、再びキー入力を確認しにいくのです。
それがＪＺ ＳＮＤです。
では、キーが押されているときは、といいますと、ＪＺ ＳＮＤをスルーして、その下の命令を実行します。
ＤＣＲ Ａです。
ＦＦコードをチェックするために、Ａレジスタの値を一律に＋１してしまいましたから、ここでもとの値に戻しているのです。
ＤＣＲ ＡはＡレジスタの値を－１します。
そうしておいて、サブルーチンＳＮＤＳＢをＣＡＬＬします。
ＳＮＤＳＢが電子オルガンプログラムのサウンド出力部分です。
ＳＮＤＳＢはＡレジスタの値に対応した（つまりキーに対応した）高さの音を一定期間出力します。
その後再びキー入力を確認するため、８０００に戻ります。
ではＳＮＤＳＢの中身を見ていくことに致します。
;
800E F5 SNDSB:PUSH PSW
800F E5 PUSH H
8010 D5 PUSH D
8011 C5 PUSH B
ＳＮＤＳＢではＡ、ＨＬ、ＤＥ、ＢＣの全てのレジスタを使いますから、最初にスタックに退避しておきます。
ＰＵＳＨはレジスタをスタックに退避する命令です。
８０８０アセンブラのニーモニックでは、Ａ、Ｂ、Ｄ、Ｈレジスタしか退避されないように思ってしまいますが、スタックへの退避は、ＡＦ（Ａレジスタとフラグレジスタ）、ＢＣ、ＤＥ、ＨＬの各ペアレジスタ単位で行われます。
ですからたとえばＰＵＳＨ Ｈは、ＨＬレジスタをスタックに退避します。
その点はＺ８０ニーモニックの方が直感的に把握できます。
Ｚ８０ニーモニックでは、ＰＵＳＨ ＨＬと書きます。
ところで、実は、この電子オルガンプログラムでは、ＳＮＤＳＢでレジスタを退避させておく必要はありません。
さきほどのメインルーチンを見てみますと、ＳＮＤＳＢを実行したあとは、また８０００のＣＡＬＬ ＫＥＹに戻っていますから、どのレジスタの値も保存しておく必要はないからです。
それではなぜ？
ということになるのですが、それはこのＳＮＤＳＢを電子オルガンプログラム以外のプログラムでも利用する、という場合を考えたからです。
Ａレジスタに音の高さを示すコードを入れて、ＳＮＤＳＢをＣＡＬＬすることで、その高さの音をわずかな時間ですが出力することができます。
電子オルガンのプログラムでは、どのレジスタの値も保存しておく必要はなかったのですけれど、別のプログラムでは、ＳＮＤＳＢをＣＡＬＬする前と後で、レジスタの値が変化してしまっては困る、ということも十分考えられます。
ここでのＰＵＳＨ命令はそのためにあります。
なお、ＰＵＳＨしたレジスタは、最後に、ＰＵＳＨしたときと逆の順番でＰＯＰ命令を使って、もとの値に戻しておく必要があります。
8012 213F80 LXI H,SNDTBL
8015 85 ADD L
8016 6F MOV L,A
8017 46 MOV B,M
8018 1E1A MVI E,1A
ＬＸＩ Ｈ，ＳＮＤＴＢＬで、プログラムの終わりにあるサウンドテーブルの先頭のアドレスをＨＬレジスタに入れています。
サウンドテーブルの中身は音の高さを決定するデータです。
ＡＤＤ Ｌ と次のＭＯＶ Ｌ，Ａ でＨＬレジスタの値（つまりサウントテーブルのアドレス）がＡレジスタの値だけ先に進みます。
ここで注意が必要なのは、このときのサウンドテーブルの上位アドレスが全部同じ（Ｈ＝８０）でなければならない、ということです。
マシン語のプログラムはこういう点に注意しなければならないときがあります。
もしもサウンドテーブルが、Ｈ＝８０とＨ＝８１にまたがっていた場合には、このプログラムの書き方では正しく実行されません。
さて、ＭＯＶ Ｂ，Ｍで、選択したサウンドテーブルの値がＢレジスタに入れられます。
その次の、ＭＶＩ Ｅ，１Ａは繰り返し回数です。
Ｅレジスタに１Ａ（＝２６）が入れられます。
801A 50 SNDS1:MOV D,B
801B 3EEF MVI A,EF;sp out=H,DMAoff
801D D398 OUT 98
801F E5 SNDS2:PUSH H;11---------
8020 E5 PUSH H;11 | 11+11+10+10+4+4+10=60
8021 E1 POP H;10 | 60/6=10
8022 E1 POP H;10 |
8023 00 NOP;4; | 10microsec
8024 15 DCR D;4 |
8025 C21F80 JNZ SNDS2;10----
いよいよ音を出力するところです。
ここでは、サウンドテーブルの値（Ｂレジスタに入っている）をダウンカウンタとして使い、一定の長さの時間を作り出します。
しかしＢレジスタはこの後のところでも使いますから、ここで壊してしまわないように、ＭＯＶ Ｄ，Ｂ命令で、Ｂレジスタの代わりにＤレジスタをダウンカウンタとして使うためにＢレジスタの値をＤレジスタにコピーしています。
ＭＯＶはｍｏｖｅですが、値がＢレジスタからＤレジスタに移動するのではなくて、Ｂレジスタの値がＤレジスタにコピーされます。
Ｉ／Ｏアドレス９８のビット５をＨにすると、スピーカーへの出力がＨになります。
と同時に音の高さを正確にするため、ＬＥＤ表示のためのＤＭＡを禁止します。
Ｉ／Ｏアドレス９８のビット４をＬにするとＤＭＡが禁止されます。
その次が、サウンドルーチンの中心になる部分です。
ＰＵＳＨ ＨからＮＯＰまでの命令は、単に時間をかせぐためだけのダミー命令です。
次のＤＣＲ ＤとＪＮＺ ＳＮＤＳ２で、この部分がサウンドテーブルの値の回数繰り返し実行されます。
ＰＵＳＨ ＨからＤＣＲ ＤとＪＮＺ ＳＮＤＳ２までの部分を１回実行するのにかかる時間は、各命令の実行クロック数の合計から求めることができます。
合計は６０クロックです。
ＮＤ８０ＺⅢのＣＰＵクロックは６ＭＨｚですから、１クロックの時間は、１／６μｓｅｃです。
ですからこの部分を１回実行するのにかかる時間は、６０／６＝１０μｓｅｃです。
ということは、Ｄレジスタの値（＝Ｂレジスタの値）、つまりサウンドテーブルの値×１０μｓｅｃの長さの時間がここで消費されることになります。
その時間、スピーカーへの出力がＨになっています。
8028 50 MOV D,B
8029 3ECF MVI A,CF;sp out=L,DMAoff
802B D398 OUT 98
802D E5 SNDS3:PUSH H;11---------
802E E5 PUSH H;11 | 11+11+10+10+4+4+10=60
802F E1 POP H;10 | 60/6=10
8030 E1 POP H;10 |
8031 00 NOP;4; | 10microsec
8032 15 DCR D;4 |
8033 C22D80 JNZ SNDS3;10----
ここも上と全く同じルーチンのようですが、繰り返しに入る前に、Ｉ／Ｏアドレス９８にＣＦをＯＵＴしています。
ビット５がＬですから、ここでスピーカー出力がＬになります。
つまりさきほどと同じ長さの時間、こんどはスピーカーへの出力がＬになります。
上の部分と合わせると、同じ期間のＨとＬのパルスが出力されることになります。
8036 1D DCR E
8037 C21A80 JNZ SNDS1
そのＨ、Ｌ出力をＥレジスタの値の回数１Ａ（＝２６回）繰り返します。
この２６回に深い意味はありません。
ここが余り短いと、キー入力を見に行く間、音が途切れる期間が無視できなくなります。
また余り長いと、キーを押しても、すぐに反応してくれません。
803A C1 POP B
803B D1 POP D
803C E1 POP H
803D F1 POP PSW
803E C9 RET
最後にスタックに退避しておいたレジスタの値をＰＯＰ命令でもとに戻してからメインルーチンにリターンします。
ここから下がサウンドテーブルです。
うーん。
これだけではわかりにくいですねえ。
;
; SOUND TABLE
803F 7F SNDTBL:DB 7F;so4
8040 77 DB 77;so#4
8041 71 DB 71;ra4
8042 6A DB 6A;ra#4
8043 5F DB 5F;do5
8044 59 DB 59;do#5
8045 54 DB 54;re5
8046 4F DB 4F;re#5
8047 47 DB 47;fa5
8048 43 DB 43;fa#5
8049 3F DB 3F;so5
804A 3B DB 3B;so#5
804B 35 DB 35;ra#5
804C 32 DB 32;si5
804D 2F DB 2F;do6
804E 2C DB 2C;do#6
804F 25 DB 25;mi6
8050 27 DB 27;re#6
8051 2A DB 2A;re6
8052 4B DB 4B;mi5
8053 38 DB 38;ra5
8054 64 DB 64;si4
8055 23 DB 23;fa6
8056 21 DB 21;fa#6
;END
KEY =0247 SND =8000 SNDS1 =801A
SNDS2 =801F SNDS3 =802D SNDSB =800E
SNDTBL =803F
ああ。
本日は時間がなくなってしまいましたので、ここの部分の詳細はまた次回にすることにいたします。
本日は、参考までに、アドレス８０５３のラ５についてのみ、簡単に説明を致します。
キーコード１４に対応する音のデータです。
キーコード１４は［ＲＥＡＤ ＩＮＣ］キーです。
ラ５はオクターブ５のラの音です。
オクターブ５のラの音の周波数は、８８０Ｈｚです。
ということは、その逆数１／８８０≒０．００１１３６ｓｅｃが周期になります。
１１３６μｓｅｃです。
その１／２の５６８μｓｅｃが、ＨまたはＬのパルスの長さ、ということになります。
そこでアドレス８０５３の値を見ていただきますと、３８になっています。１０進数に直すと５６です。
さきほどのパルス出力のところで、サウンドテーブルの長さ×１０μｓｅｃがＨまたはＬのパルスの長さになります、という説明をしました。
ということは、５６×１０＝５６０μｓです。
８８０Ｈｚから算出した値５６８μｓｅｃよりも８μｓｅｃ短いですけれど、この部分は、クロックの計算からは落ちているスピーカーへの出力のＨ、Ｌを切り換えるためのＯＵＴ命令や、ＭＯＶ Ｄ，Ｂ命令、ＤＥＣ Ｅ、ＪＮＺ命令などの時間を考慮して、理論値を超えない値にしてあります。
スピーカーへのラ５の音（８８０Ｈｚ）の出力波形です。
２０１０．７．２１ｕｐｌｏａｄ
前へ
次へ
ホームページトップへ戻る