マイコン独立大作戦
ＳＤカードインターフェースの製作
～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～
ＷｉｎｄｏｗｓパソコンにＵＳＢ接続して使う現行方式はそれなりに便利ではありますが、ときとしてＷｉｎｄｏｗｓ
のしがらみから開放されて、小さいながらも独立した一個のパソコンとして機能したいと思うこともあります。
独立大作戦の作戦その１はＣＲＴインターフェースボードの製作です。
作戦その２はキーボードインターフェースです。
そして作戦その３は、ＳＤカードインターフェースです。
～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～～
［第９回］
●テストプログラムの説明
ＩＮ／ＯＵＴサブルーチンから先に説明します。
下がサブルーチンＳＩＮＯＵＴのアセンブルリストです。
テストプログラム全体のリストは前回にあります。
; D:out data E:in data
816E 0608 SINOUT:LD B,08
8170 7A SINOUT2:LD A,D
8171 2F CPL
8172 D381 OUT (81),A;data out
8174 3E01 LD A,01
8176 D383 OUT (83),A;pc0=1 out ~I_
8178 7A LD A,D
8179 17 RLA
817A 57 LD D,A
817B 3E00 LD A,00
817D D383 OUT (83),A;pc0=0 out _I~
817F DB80 IN A,(80)
8181 2F CPL
8182 1F RRA
8183 7B LD A,E
8184 17 RLA
8185 5F LD E,A;data in
8186 05 DEC B
8187 C27081 JP NZ,SINOUT2
818A 3E01 LD A,01
818C D383 OUT (83),A;pc0=1 out ~I_
818E C9 RET
;
|
最初にＤレジスタの内容（８ビット）を８２Ｃ５５のＢポートから出力します。
７４ＨＣ０５によって出力が反転しますから、送出する前に値を反転しておきます。
そのときのＤレジスタの値を反転した８ビットの値がＰＢ７～ＰＢ０から出力されますが、ＭＯＳＩのラインには７４ＨＣ０５を介してＰＢ７しかつながっていませんから、結局そのときのＤレジスタのビット７の値のみがＳＤカードに伝えられることになります。
Ｄレジスタのビット７の値がＰＢ７から出力された直後に、ＰＣ０から１を出力します。
出力は７４ＨＣ０５によって反転されますから、ＳＣＫのラインがＨからＬになります。
逆にＰＣ０から０（Ｌ）を出力すると、ＳＣＫのラインはＨになります。
ここでの注意は、ＣポートからはＳＣＫのほかにＣＳも出力される（ＰＣ１）という点です。
ＰＣ０からＳＣＫを出力するときにＰＣ１の出力が変わってしまわないように、ＰＣ０のみを出力するようにします（Ｃポートのビット出力モードを使います）。
通常はこのサブルーチンが呼ばれた時点でＳＣＫラインはＬになっていますから、第１回目のパルス出力（アドレス８１７６）は冗長ですが、プログラムの流れでこのようになります。
ビットデータ送出後にＤレジスタの値を１ビット左シフトします。
こうすることでＰＢ７からＤレジスタの値がパラレルからシリアルに変換されて出力されることになります。
Ｚ８０には各レジスタを直接シフトする命令がありますが、ＭＹＣＰＵ８０やＮＤ８０８０との互換性を考えて、８０８０の命令だけでプログラムします。
前回確認しました通りパルス出力周波数はＳＤカードの規定値よりも低いので、特に待ち時間ループなどを挿入することなく、Ｄレジスタを左シフトしたらすぐにＳＣＫ出力をＨにします。
そして直後にＳＤカードからのデータをＰＡ０から入力します。
７４ＨＣ０５によって入力データも反転しますから、入力したら値を反転します。
入力データはＥレジスタに入れますがここでテクニックを使っています。
先にＲＲＡコマンドでＡレジスタを右シフトします。
こうするとＰＡ０から入力したデータ（Ａレジスタのビット０）がキャリーフラグに入ります。
そのあとでＥレジスタを左シフトします。
するとＥレジスタがビット７←ビット０の方向に１ビットシフトされて、ビット０にはキャリーフラグの値が入ります。
以上の動作を８回繰り返すと、Ｄレジスタの値８ビットがシリアル送出され、ＳＤカードからのデータ８ビットがＥレジスタに読み込まれます。
最後にＳＣＫ出力をＬにします。
このようにＳＰＩ通信を８２Ｃ５５を使って行なう場合、このＳＩＮＯＵＴサブルーチンが肝心要（かなめ）の部分で、これさえ出来れば、あとはフロー通りにプログラムするだけです。
肝心要のＳＩＮＯＵＴサブルーチンの説明が済みましたので、次にメインプログラムの説明に入ります。
［第７回］にフローチャートがありますから、適宜参照してください。
8100 3E90 START0:LD A,90
8102 D383 OUT (83),A
;card init
8104 2E0A LD L,0A
8106 CD6E81 START01:CALL SINOUT
8109 2D DEC L
810A C20681 JP NZ,START01
|
最初に８２Ｃ５５の向きを設定します。
Ａポートが入力でＢポート、Ｃポートを出力に設定します。
コントロールワード９０Ｈをアドレス８３Ｈに出力します。
出力に設定したポートは全ビットが０になります。
７４ＨＣ０５によってラインの出力は反転しますから、８２Ｃ５５の向きを設定すると、ラインの出力はＨになります。
ＣＳラインをＨにしたままでＳＣＫパルスを７４回以上送ります。
１回のＳＩＮＯＵＴサブルーチンコールで８パルスが出力されますから、サブルーチンを１０回（０ＡＨ）コールして、８０パルス出力します。
ここでうっかりしてＤレジスタをＨにするのを忘れていました。
このときＭＯＳＩラインからはＤレジスタの値（何が入っているかは不明）が出力されてしまいます。
幸いＣＳがＨの状態なので、このまま実行しても特に支障はありませんでした。
次はＣＭＤ０の送出です。
;CMD0 out
810D 3E02 LD A,02
810F D382 OUT (82),A;CS=L
8111 1640 LD D,40
8113 CD6E81 CALL SINOUT
8116 0604 LD B,04
8118 C5 START02:PUSH BC
8119 1600 LD D,00
811B CD6E81 CALL SINOUT
811E C1 POP BC
811F 05 DEC B
8120 C21881 JP NZ,START02
8123 1695 LD D,95
8125 CD6E81 CALL SINOUT
8128 16FF START03:LD D,FF
812A CD6E81 CALL SINOUT
812D 63 LD H,E
812E 7B LD A,E
812F F5 PUSH AF
8130 CD4B10 CALL HXDP2
8133 F1 POP AF
8134 FE01 CP 01
8136 C22881 JP NZ,START03
;
|
ここからはＣＳをＬにします。
７４ＨＣ０５によってラインの出力は反転しますから、ＰＣ１を１にします。
ＤレジスタにＣＭＤ０（４０ ００ ００ ００ ００ ９５）をセットしてＳＩＮＯＵＴサブルーチンをコールします。
送出したらＦＦを出力しながらレスポンスを待ちます。
その状態をモニタするために８ビット受信するごとに１６進数２桁で画面表示します。
ＨＸＤＰ２はＨレジスタの値を１６進数２桁で表示するＺＢ３ＢＡＳＩＣのシステムサブルーチンです。
レスポンス０１が来たら次の処理（ＣＭＤ１の送出）に移ります。
ＣＭＤ１の送出です。
;CMD1 out
8139 1641 START07:LD D,41
813B CD6E81 CALL SINOUT
813E 0604 LD B,04
8140 C5 START08:PUSH BC
8141 1600 LD D,00
8143 CD6E81 CALL SINOUT
8146 C1 POP BC
8147 05 DEC B
8148 C24081 JP NZ,START08
814B 16FF LD D,FF
814D CD6E81 CALL SINOUT
8150 16FF START09:LD D,FF
8152 CD6E81 CALL SINOUT
8155 63 LD H,E
8156 7B LD A,E
8157 F5 PUSH AF
8158 CD4B10 CALL HXDP2
815B F1 POP AF
815C B7 OR A;00?
815D CA6881 JP Z,END
8160 FE01 CP 01
8162 C25081 JP NZ,START09
8165 C33981 JP START07
8168 CD1B10 END:CALL CRLF
816B C33310 JP REENT
;
|
ＤレジスタにＣＭＤ１（４１ ００ ００ ００ ００ ＦＦ）をセットしてＳＩＮＯＵＴサブルーチンをコールします。
送出したらＦＦを出力しながらレスポンスを待ちます。
その状態をモニタするために８ビット受信するごとに１６進数２桁で画面表示します。
レスポンス００が来たら処理を終ります（ＥＮＤ：にジャンプします）。
００、０１以外ならＳＴＡＲＴ０９：に戻ってレスポンスを待ち続けます。
０１ならＳＴＡＲＴ０７：に戻ってＣＭＤ１を送出して、以後の処理を繰り返します。
ＥＮＤ：では表示を改行するため、ＣＲＬＦをコールしたあと、システムに戻ります。
ＣＲＬＦは画面表示を改行するＺＢ３ＢＡＳＩＣのシステムサブルーチンです。
ＲＥＥＮＴはＺＢ３ＢＡＳＩＣシステムに戻るエントリポイントです。
●テストプログラムの実行
テストプログラムｓｄｃｄｉｆ２ｋ．ｂｉｎをＮＤ８０Ｚ３．５で実行しました。
logfile nd80zlog\11031038.txt open ＮＤ８０ＺⅢに接続しました 0001 0000 - z 1000 00C3 - *** nd80z3 basic **** ndwr2h.bin loaded,from E23F to E535 >/ld sdcdif2k.bin,8100 loading SDCDIF2K.BIN ...008f(143)bytes loaded,from 8100 to 818E >jp 8100 FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01 FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01FF01 FF01FF01FF00 >jp 8100 FF01FF01FF00 >/exit 0000 00C3 - リモート接続を終了しました logfile closed at Thu Nov 03 10:41:20 2016 |
このテストプログラムはＣＭＤ０とＣＭＤ１をＳＤカードに送って初期化を実行するだけのプログラムです。
ＣＭＤ０、ＣＭＤ１を送ってレスポンスを確認するだけです。
カードの読み出しなどはしていません。
プログラムを２回実行しています。
１回目は電源投入直後なので、ＣＭＤ１で００が来るまでに少し時間がかかっています。
ＦＦ０１が連続しています。
先頭のＦＦ０１はＣＭＤ０のレスポンスです。
次からのＦＦ０１はＣＭＤ１のレスポンスです。
２回目のプログラム実行ではすぐに００が来ました。
どうやらここまではうまくいったようです。
ＳＤカードインターフェースの製作［第９回］
２０１６．１１．４ｕｐｌｏａｄ
前へ
次へ
ホームページトップへ戻る