［新連載開始］Ｗ６５Ｃ０２マイコンボードの製作
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
私としてはＷ６５Ｃ０２をさわるのは全く初めてです。何から何まで未経験です。さてどうなりますでしょうか。
〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜

［第６２回］



●ＢＲＫ，ＮＯＰ，ＳＴＰ

ＮＯＰはＮｏ　Ｏｐｅｒａｔｉｏｎです。
何もしない命令です。
実行によってフラグやレジスタに影響を与えません。
単にプログラムのアドレスを調整するとかパルス出力幅を調整する「時間稼ぎ」のためなどに使われます。
ＳＴＰはプログラムの実行を停止して静止モードになります。
後の回で説明する予定のＷＡＩと違って割込みによって静止を解除することはできません。
外部からのリセット入力によってのみ解除できます。
ＮＯＰとＳＴＰはこれまでの回でテストプログラムに使ってきていますのであらためてテストプログラムは作成しません。
今回の主役はＢＲＫです。
ＢＲＫの説明に入る前にまずは各命令のコードなどについて下にまとめておきます。

ニーモニック	マシン語コード	アセンブラ書式	バイト数	クロック数
ＢＲＫ	００	ＢＲＫ	１	７
ＮＯＰ	ＥＡ	ＮＯＰ	１	２
ＳＴＰ	ＤＢ	ＳＴＰ	１	−

ＢＲＫはソフトウェア割込み命令です。
ＢフラグとＩフラグがセットされます。
Ｂフラグ（ビット４）はＢｒｅａｋフラグです。
Ｉフラグ（ビット２）は割込み禁止フラグです。
ＢＲＫはプログラムデバッグのための特殊な割込み命令として用意されたと理解しています。
Ｚ８０や８０８０のＲＳＴ７（コードＦＦ）と同じ用途です。
プログラムのデバッグをしたいときにブレークをさせたいところにこの命令（実用上は命令コード）を上書きします。
その使い方からデバッグの対象はＲＡＭ上のプログラムということになります。
ＲＳＴ７と違ってコードが００なのでＲＯＭのプログラムでも上書き可能であるという解説をネット上で見ました。
コードが００なのはそういう理由からかもしれません。
通常の割込みと異なり割り込み禁止フラグ（Ｉフラグ）の状態に関係なく実行可能です。
通常の割込みと同じで割込みジャンプテーブル（アドレスＦＦＦＥ、ＦＦＦＦ）に記載されたアドレスにジャンプするので事前にＢＲＫサービスプログラムのアドレスを書いておきます。
ＢＲＫ割込みが発生するとその時点のＰＣ（プログラムカウンタ）に＋２した値とフラグレジスタの値をスタックにＰＵＳＨした後にＢＲＫサービスプログラムにジャンプします。
そのあたりの確認ということも含めてテストプログラムを作成しました。

;w65c02test36 26/8/13
;
;BRK
;
        org $8000
;
        lda #$10
        sta $fffe
        lda #$80
        sta $ffff
        ldx #$fd
        txs
        cli
        bra start
;
braek:
        tsx
        stx $01
        stp
;
start:
        stx $00
        inc
        adc #$12
        sta $03
        brk
        tsx
        stx $02
        stp
;end

Ｗ６５Ｃ０２アセンブラでアセンブルしました。

下はアセンブルの結果作成されたアセンブルリストです。

0000        ;w65c02test36 26/8/13
0000        ;
0000        ;BRK
0000        ;
8000            org $8000
8000        ;
8000 A910       lda #$10
8002 8DFEFF     sta $fffe
8005 A980       lda #$80
8007 8DFFFF     sta $ffff
800A A2FD       ldx #$fd
800C 9A         txs
800D 58         cli
800E 8004       bra start
8010        ;
8010        braek:
8010 BA         tsx
8011 8601       stx $01
8013 DB         stp
8014        ;
8014        start:
8014 8600       stx $00
8016 1A         inc
8017 6912       adc #$12
8019 8503       sta $03
801B 00         brk
801C BA         tsx
801D 8602       stx $02
801F DB         stp
8020        ;end

上で書きましたように本来はデバッグするのが目的なのでプログラム中に書いておくのではなくでデバッグのときにブレークしたいところにＢＲＫコードを上書きするという使い方になるかと思いますが今回はテストなのでプログラム中に置いてあります。
ＢＲＫはソフトウェア割込みであることを除けば通常の外部割込み（ＩＲＱ端子から入力）と同じです。
後でわかったことですが外部割込みと違ってＢＲＫはＩフラグの状態に関係なく実行可能なのだそうです（後で確認します）。
ＢＲＫが実行されるとシステムジャンプテーブルＦＦＦＥ、ＦＦＦＦに書いてあるアドレスにジャンプします。
今回のテストプログラムではプログラムの先頭でＢＲＫプログラムの先頭アドレス（８０１０）をＦＦＦＥ、ＦＦＦＦに入れておきます。
そしてスタックポインタにスタックの先頭アドレスとしてＦＤを入れるとともに記録として＄００にも同じスタックポインタの値（ＦＤ）を入れます。
スタックについてちょっとまだ迷いがあったころに書いたプログラムなのでＦＤなどというハンパな値を設定しています。
最初にこのプログラムを書いた時点ではＢＲＫの実行にはＩフラグ＝０が条件かと誤解していましたのでＣＬＩ命令を使っています。
ＢＲＫプログラムによってスタックに保存されるフラグレジスタの値を確認する目安になるようにＢＲＫ命令の直前に実行される演算の結果の値（アキュムレータの値）を＄０３にセーブしておきます。
プログラムはアドレス８０１Ｂでブレークします。
ＢＲＫプログラムが実行されたことがわかるようにアドレス＄０１にそのときのスタックポインタの値を入れます。
ＢＲＫプログラムの最後にＳＴＰがありますからそこで停止します。
ＢＲＫが正しく実行されればアドレス８０１Ｃから後ろは実行されないはずです。
もし実行されたら＄０２にそのときのスタックポインタの値が入ります。

６５ｃ０２ｔｅｓｔ３６．ｂｉｎをロードしました。
実行前に＄００〜＄０３をＦＦにしておきます。

／ＲＵＮでプログラムを実行しました。
実行後に／ＣＭで確認したところ次の通りでした。
００００　ＦＤ　　　プログラム開始時のスタックポインタの値
０００１　ＦＡ　　　ＢＲＫプログラムにエントリしたときのスタックポインタの値
０００２　ＦＦ　　　変化なし
０００３　９３　　　アキュムレータの値
０００２が変化なしなので８０１Ｃ以後は実行されなかったことがわかりました。

／ＤＭ　０１を実行してスタックエリアを表示させました。


ＢＲＫが読み込まれたときのプログラムカウンタの値＋２がスタックに保存されます。
ＢＲＫは８０１Ｂにあります。
スタックにはその値＋２が入りますから８０１Ｂ＋２＝８０１Ｄです。
おお。
合ってますね。
次はフラグです。

０１ＦＢにはフラグレジスタの値が入ります。
Ｂ０です。
ＢＲＫの直前にＩＮＣとＡＤＣ　＃＄１２が実行されています。
その前のアキュムレータの値は＄８０です。
８０＋１＋１２＝９３ですから＄０３の値と一致しています。
そのときのフラグはＮ＝１、Ｖ＝０、Ｚ＝０、Ｃ＝０ですがＢＲＫの実行によってＢ（ビット４）とＩ（ビット２）がセットされますから１０１１０１００（Ｂ４）になるはずなのですが。
あれ？
ビット２が０？
で。
Ｇｏｏｇｌｅ様にお聞きしましたら。
Ｉフラグは直前の値をそのままスタックに退避するのだそうです。
なるほどそれで０になるということか。
その後にＣＰＵ内部で割込み禁止にするためＩフラグがセットされるのだそうです。
ついでにＤフラグ（ビット３。十進モードフラグ）は強制的にクリアされるのだそうです。
うむむ。
よくわからん仕様であります。

上の方に書きましたが。
確かＧｏｏｇｌｅで確認したときＢＲＫはＩフラグに関係なく実行されると書いてあったような。
再確認したところ確かにそう書いてありました。
ならば。
再テストするよりほかはないでしょう。
そこを意識してあえてＩフラグをセットしてテストしました。
ＣＬＩをＳＥＩに変更しました。

;w65c02test36b 26/8/13
;
;BRK
;
        org $8000
;
        lda #$10
        sta $fffe
        lda #$80
        sta $ffff
        ldx #$fd
        txs
        sei
        bra start
;
braek:
        tsx
        stx $01
        stp
;
start:
        stx $00
        inc
        adc #$12
        sta $03
        brk
        tsx
        stx $02
        stp
;end

Ｗ６５Ｃ０２アセンブラでアセンブルしました。

0000        ;w65c02test36b 26/8/13
0000        ;
0000        ;BRK
0000        ;
8000            org $8000
8000        ;
8000 A910       lda #$10
8002 8DFEFF     sta $fffe
8005 A980       lda #$80
8007 8DFFFF     sta $ffff
800A A2FD       ldx #$fd
800C 9A         txs
800D 78         sei
800E 8004       bra start
8010        ;
8010        braek:
8010 BA         tsx
8011 8601       stx $01
8013 DB         stp
8014        ;
8014        start:
8014 8600       stx $00
8016 1A         inc
8017 6912       adc #$12
8019 8503       sta $03
801B 00         brk
801C BA         tsx
801D 8602       stx $02
801F DB         stp
8020        ;end

先ほどと同じようにテストしました。
６５ｃ０２ｔｅｓｔ３６ｂ．ｂｉｎをロードしました。
＄００〜＄０３をＦＦにしてから／ｒｕｎを実行しました。

／ＣＭコマンドで＄００〜＄０３を確認して先ほどと同じ結果であることが確認できました。
＄０１がＦＡになりましたからＩフラグがセットされていてもＢＲＫが実行されることが確認できました。

／ＤＭコマンドでスタックを表示させました。


Ｗ６５Ｃ０２マイコンボードの製作［第６２回］
２０２６．９．２　ｕｐｌｏａｄ

前へ
次へ
ホームページトップへ戻る